function readexample,pulno,signal,xVal
	;This is an example function to demonstrate how to read data into JETDSP
	;using the signal processing functions. This example requires the JPF system.
	; The example reads data from the KY6 spectrometer, this is 3D data, and only
	; slice of the data is shown.


	;This defines the return structure that needs filling with the values.

	resultStruct={JetProcSignal	$
		,data:ptr_new()		$
		,time:ptr_new()		$
		,x:ptr_new()		$
		,type:''		$
		,tAxisType:0		$
		,xAxisType:0		$
		,multigraph:0		$
		,n_multi:1		$
		,slice:''		$
		,status:0		$
		}

	; Assume success.
	resultStruct.status=1

	; convert signal number into string.
	signalNumStr=strtrim(string(signal),2)

	; append this string to each signal name.
	;This is the data signal
	signal='DH/Y6-SPEC:00'+signalNumStr
	;This signal contains one value corresponding to the number of X points.
	xSizeSignal='DH/Y6-ACTSEG<MPX:00'+signalNumStr
	;This signal contains one value corresponding to the number of Y points.
	ySizeSignal='DH/Y6-NTRACK<MPX:00'+signalNumStr
	;This signal contains one value corresponding to the number of T points.
	tSizeSignal='DH/Y6-NFRAME<MPX:00'+signalNumStr

	; read the data.

	; get the number of x points.
	jpfraw, node=xSizeSignal, pulno=pulno, data=nXarr, ier=ier, /dcache
	; get the number of y points.
	jpfraw, node=ySizeSignal, pulno=pulno, data=nYarr, ier=ier, /dcache
	; get the number of t points(requested points from node).
	jpfraw, node=tSizeSignal, pulno=pulno, data=nTarr, ier=ier, /dcache
	; get the time points for the data signal.
	jpftim,node=signal, pulno=pulno,tvec=time, /dcache

	; explicitly calculate size for data array.
	nX=nXarr[0]
	nY=nYarr[0]
	nwds=nX*nY*n_elements(time)

	; read the data siganl from the JPF system
	jpfraw, node=signal, pulno=pulno, data=data, ier=ier, nwds=nwds, /dcache

	; quick check to see if we have got it all.
	nT=n_elements(data)/(nX*nY)	;should equal n_elements(tvec)
	if nT ne n_elements(time) then begin
		resultStruct.status=0
	endif

	;The data comes back as a vector, therefore shape the data correctly.
	data=reform(data,nX,nY,nT)

	; return the error flag from the last call.

	if ier eq 0 then begin
		;swap indices to put time first and unused dimension last.
		;this is automatically removed.
		resultStruct.data=ptr_new(transpose(data[xVal,*,*],[2,1,0]))
		resultStruct.time=ptr_new(time)
		resultStruct.x=ptr_new(indgen(nyArr[0]))	;Dummy array of correct size
		resultStruct.type='3D'
		; nothing else needed.
	endif else begin
		resultStruct.status=0
	endelse
	return,resultStruct
end